Originally posted by: Darth Editous
Those lines look completely separated - in such a case you'll be hard pushed to find a plugin that will join 'em all up - without causing horrible artefacts elsewhere as well.

DE

Originally posted by: Moth3r
I'd given up on those jaggies. I'm just going to stick to the improvement offered by a simple EEDI2().

I also tried DeGrainMedian in conjunction with MVDegrain2. It performed slightly better at removing grain but unfortunately removed detail out of motion/panning scenes (which are already in poor shape after being trashed by the '90s DVNR algorithms).

Yeah, those jaggies are probably well beyond any attempt at automatic fixing. In any case, if you're going to use EEDI2, I'd strongly recommend you in the way I mentioned earlier:

EEDI2().TurnRight().EEDI2().TurnLeft()

# Crop and upsize using anti-aliasing
# Use less aggressive settings for the probe droid
# interrogation scene to avoid artefacts

a=mpeg2source("e:\project.d2v").crop(0,102,0,-104).eedi2().trim(0,58642)
b=mpeg2source("e:\project.d2v").crop(0,102,0,-104).eedi2(maxd=15,nt=8).trim(58643,-351)
c=mpeg2source("e:\project.d2v").crop(0,102,0,-104).eedi2().trim(58994,0)
source=a+b+c

# Adjust the luma (Y) levels
# with a little function I found at Doom9. A modification of Didée's YLevels,
# this one gives a lower brightness and increased contrast
# without excessive "crunching" or "clipping"

source.FlimsYLevels(10)

# Subtle grain filtering for hot pixel removal

DeGrainMedian(limitY=5,limitUV=5,mode=3)

# Adjust colour, more saturation, less pink

tweak(sat=1.15, hue=-6.25)

# Sharpen and resize to NTSC DVD resolution

limitedsharpenfaster(dest_x=720, dest_y=366)
addborders(0,57,0,57)

# Add subtitles for Greedo scene
# Approximate match for theatrical font and position,
# compressed horizontally to keep text within overscan "safe area"
# Note you need AviSynth 2.58 Alpha for the font_width parameter

subtitle ("Going somewhere, Solo?", \
-1,370,70663,70698, \
"Franklin Gothic Demi Cond",36,$ffffff,font_width=10.5)
subtitle ("It’s too late. You should have paid him when you had the chance.", \
-1,370,70825,70931, \
"Franklin Gothic Demi Cond",36,$ffffff,font_width=10.5)
subtitle ("Jabba’s put a price on your head so large every\n" + \
"bounty hunter in the galaxy will be looking for you...", \
85,330,70940,71088, \
"Franklin Gothic Demi Cond",36,$ffffff,font_width=10.5,lsp=1)
subtitle ("I’m lucky I found you first.", \
-1,370,71098,71137, \
"Franklin Gothic Demi Cond",36,$ffffff,font_width=10.5)
subtitle ("If you give it to me, I might forget I found you.", \
-1,370,71203,71282, \
"Franklin Gothic Demi Cond",36,$ffffff,font_width=10.5)
subtitle ("Jabba’s through with you.", \
-1,370,71365,71406, \
"Franklin Gothic Demi Cond",36,$ffffff,font_width=10.5)
subtitle ("He has no time for smugglers...", \
-1,370,71435,71489, \
"Franklin Gothic Demi Cond",36,$ffffff,font_width=10.5)
subtitle ("...who drop their shipments at the first sign of an Imperial cruiser.", \
-1,370,71498,71595, \
"Franklin Gothic Demi Cond",36,$ffffff,font_width=10.5)
subtitle ("You can tell that to Jabba. He may only take your ship.", \
-1,370,71656,71748, \
"Franklin Gothic Demi Cond",36,$ffffff,font_width=10.5)
subtitle ("That’s the idea.", \
-1,370,71806,71833, \
"Franklin Gothic Demi Cond",36,$ffffff,font_width=10.5)
subtitle ("I’ve been looking forward to this for a long time.", \
-1,370,71843,71931, \
"Franklin Gothic Demi Cond",36,$ffffff,font_width=10.5)

function FlimsYlevels(clip clp, float amp)
{ wicked="x x 16 - 34,85493 / sin "+string(amp)+" * -"
return( clp.mt_lut(Yexpr = wicked) )
}